" .vimrc
" 07feb2008  +chris+
" 29sep2009  +chris+
" 14aug2019  +leah+  clean up
autocmd!

" General options
set rulerformat=%-13.(%l/%L%)\ %P
set ruler
set tabstop=8
set softtabstop=2
set shiftwidth=2
set expandtab
autocmd BufRead * silent g/^\t/setl sts=0 sw=8 noet|norm!``
autocmd BufNewFile,BufRead template setl sts=0 sw=0 noet nf-=octal
set visualbell
set backup
autocmd BufNewFile,BufRead *:2\,* setl nobackup ft=mail
set autoread
set textwidth=70
set virtualedit=block
set history=100
set viminfo+=%
set showcmd
set titlestring=%{hostname()}:\ vim\ %F%a

" More Emacsish
set backspace=indent,eol,start
set selection=exclusive
set incsearch
set shiftround
set joinspaces
set whichwrap+=<,>
set ignorecase
set smartcase
set showmatch
set nohlsearch
set hidden
set winminheight=0
cmap <C-G> <C-C>
set showbreak=\\
set cinkeys=0{,0},:,0#,0<Tab>,!^F
set noautoindent
set nofixeol
set display+=truncate

" no lame menus
set wildmenu
set completeopt=preview
set wildmode=longest,list

" annoys to no end
map q: :
set cedit=^F
set nofoldenable
set t_ti= t_te=  " dont use secondary screen
command! -bang -nargs=? -complete=file W w<bang> <args>
command! -bang -nargs=? -complete=file Wq wq<bang> <args>
command! -bang -nargs=? -complete=file WQ wq<bang> <args>
" behaves like :q for windows, but for buffers
command! -bang Q :if len(filter(range(1,bufnr('$')),'bufloaded(v:val)'))==1 | q<bang> | else | bd<bang> | endif
command! -nargs=? Help help <args>

" shortcuts for quickfix
nnoremap <silent> _ :cprev<CR>
nnoremap <silent> + :cnext<CR>
nnoremap <expr> <silent> <leader><leader> &buftype ==# 'quickfix' ? ':bd<CR>' : ':cw\|silent only<CR>'
" close quickfix after jumping
autocmd BufReadPost quickfix nmap <silent> <buffer><CR> :.cc\|silent only<CR>

" no wrap in quickfix
" 01sep2016  +chris+
autocmd BufReadPost quickfix setl nowrap

" shortcuts for cycling buffers
" 21dec2018  +leah+
nnoremap <C-N> :bn<CR>
nnoremap <C-P> :bp<CR>

" .xbps files
" 03feb2017  +leah+
au BufReadCmd *.xbps call tar#Browse(expand("<amatch>"))

" resize windows on terminal size change
autocmd VimResized * wincmd =

let g:tex_flavor='pdflatex'
let s:tlist_def_tex_settings = 'tex;s:section;c:chapter;l:label;r:ref'
let g:surround_{char2nr('c')} = "\\\1command\1{\r}"
runtime macros/matchit.vim
filetype plugin indent on
try
  syntax on
  colorscheme chris2
  # disable conceal in help
  autocmd FileType help syn off
catch
  syntax off
  set background=dark
endtry

" === custom stuff ===

" zi: insert one char
map zi i$<ESC>r

" Q reflows the current paragraph/selection
map Q gwap
vmap Q gq

" custom text-objects (thx romainl)
for char in [ '_', '.', ':', ',', ';', '<bar>', '/', '<bslash>', '*', '+', '%', '$' ]
  execute 'xnoremap i' . char . ' :<C-u>normal! T' . char . 'vt' . char . '<CR>'
  execute 'onoremap i' . char . ' :normal vi' . char . '<CR>'
  execute 'xnoremap a' . char . ' :<C-u>normal! F' . char . 'vf' . char . '<CR>'
  execute 'onoremap a' . char . ' :normal va' . char . '<CR>'
endfor

" aa selects everything in visual selection mode
xnoremap aa <ESC>:mark ' \| keepj norm! ggVG<CR>

" keep visual selection when reindenting
xnoremap > >gv
xnoremap < <gv

" backgrounding in insert mode
inoremap <C-Z> <C-O>:stop<CR>

" whitespace under cursor as text object
onoremap <silent> a<space> :let r=@/ \| let @/="\\s*\\(\\%#\\&\\s\\)\\s*" \| :exe "normal! gn" \| let @/=r<CR>
onoremap <silent> i<space> :let r=@/ \| let @/="\\s\\@<=\\s*\\(\\%#\\&\\s\\)\\s*" \| :exe "normal! gn" \| let @/=r<CR>

" compress whitespace
" nmap g<space> :s/\s*\%#\s*/ /e<CR>
nmap g<space> da<Space>i<Space><ESC>

" yay, emacs-style command line editing
cnoremap <C-A> <Home>
cnoremap <C-E> <End>
cnoremap <C-D> <Del>
cnoremap <C-K> <C-\>estrpart(getcmdline(),0,getcmdpos()-1)<CR>

" save as root
command! WW :w !sudo tee % >/dev/null

" diffput current line only
nmap dP :.diffput<CR>

" g. to open directory file is in
nmap g. :e %:h<CR>

" g* to execute the current line as macro
nmap g* my"yyy@y`y

" g! to execute the current line as shell command
nmap g! :exe "!".getline('.')<CR>

" jump to the next end-of-word location, and reenter insert mode
" https://math.berkeley.edu/~gbergman/misc/hacks/vi.html
imap <C-E> <ESC>Ea

" easier "0p
nnoremap 0p "0p

" easier :%s///g
nnoremap S :%s//g<Left><Left>
vnoremap S :s//g<Left><Left>

" g= indent line/selection as much as line above
nmap <silent> g= :le <C-R>=indent(line('.')-1)<CR><CR>
vmap <silent> g= :'<,'>le <C-R>=indent(line('v')-1)<CR><CR>

" Various Leader macros
" sort words in string
nmap <silent> <Leader>r :.!perl -pe 's/"\K(.*?)(?=")/join(" ",sort(split(" ", $1)))/eg'<CR>
" put word in braces
nmap <Leader>q bi{<ESC>ea}<ESC>
" insert date in my format
nmap <Leader>d a<C-R>=tolower(strftime("%d%b%Y"))."  +".$USER."+"<CR><ESC>
" keep .orig
nmap <Leader>o :set patchmode=.orig<CR>
" load haskell
nmap <Leader>l :call term_sendkeys('!ghci', ":load ".expand('%:p')."\r")<CR>
" sort paragraph (e.g. includes)
nmap <Leader>s vip:sort<CR>
" bump revisit timestamp
nmap <Leader>b :.!revisit -b<CR>

" fix my name
command! Leah %s/Christian Neukirchen <chneukirchen@gmail.com>/Leah Neukirchen <leah@vuxu.org>/ge | %s/chneukirchen@gmail.com/leah@vuxu.org/ge | %s/Christian Neukirchen/Leah Neukirchen/ge | %s/+chris+/+leah+/ge | %s/chris2/leah2/ge

" :R to execute command with output to a scratch buffer
command! -n=* -complete=shellcmd R new|setl bt=nofile noswf|exe "0r!" <q-args>|0

" :Lr to wrap lr(1) and open files on return
command! -n=* -complete=file Lr silent exe "R" "lr" <q-args> | res | silent f [lr] | map <buffer><CR> $hgF

" :Mo to move last visual to the line below
command! Mo k` | '<,'>m . | norm ``j

" disable automatic insertion of comment markers
set fo=cjql
autocmd FileType * setl fo-=o fo-=r
autocmd FileType gitcommit setl fo=cjql com+=n:>

let g:netrw_http_cmd="curl -Ls -o"
let g:netrw_ftp_cmd="tnftp"
let g:netrw_uid="anonymous"
" hide dotfiles by default, use 'a' to cycle
let g:netrw_list_hide='\(^\|\s\s\)\zs\.\S\+'

let g:GPGExecutable="gpg2"

set dictionary=/usr/share/dict/words

if has("gui_running")
  set columns=80
  set lines=50
  set guifont=Fixed\ Medium\ Semi-Condensed\ 10

  " Lightweight interface
  set guioptions=aegitl

  " Nonblinking cursor
  set gcr=a:blinkon0
endif

if &diff
  " don't fold
  set diffopt+=context:1000000
  highlight! link DiffText MatchParen
  highlight! link DiffChange Normal
  highlight! link DiffDelete Conceal
end

" hard mode
" 06jun2016  +chris+
noremap <up> <nop>
noremap <down> <nop>
noremap <left> <nop>
noremap <right> <nop>
inoremap <up> <nop>
inoremap <down> <nop>
inoremap <left> <nop>
inoremap <right> <nop>

" site-local config
" 31oct2017  +leah+
silent! source ~/.vimrc.local